codeql/python/ql/src/analysis/AlertSuppression.ql at next · github/codeql · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
/**
 * @name Alert suppression
 * @description Generates information about alert suppressions.
 * @kind alert-suppression
 * @id py/alert-suppression
 */

import python

/**
 * An alert suppression comment.
 */
abstract class SuppressionComment extends Comment {

    /** Gets the scope of this suppression. */
    abstract SuppressionScope getScope();

    /** Gets the suppression annotation in this comment. */
    abstract string getAnnotation();

    /**
     * Holds if this comment applies to the range from column `startcolumn` of line `startline`
     * to column `endcolumn` of line `endline` in file `filepath`.
     */
    abstract predicate covers(string filepath, int startline, int startcolumn, int endline, int endcolumn);

}

/**
 * An alert comment that applies to a single line
 */
abstract class LineSuppressionComment extends SuppressionComment {

    LineSuppressionComment() {
        exists(string filepath, int l |
            this.getLocation().hasLocationInfo(filepath, l, _, _, _) and
            any(AstNode a).getLocation().hasLocationInfo(filepath, l, _, _, _)
        )
    }

    /** Gets the scope of this suppression. */
    override SuppressionScope getScope() {
        result = this
    }

    override predicate covers(string filepath, int startline, int startcolumn, int endline, int endcolumn) {
        this.getLocation().hasLocationInfo(filepath, startline, _, endline, endcolumn) and
        startcolumn = 1
    }

}

/**
 * An lgtm suppression comment.
 */
class LgtmSuppressionComment extends LineSuppressionComment {

    string annotation;

    LgtmSuppressionComment() {
        exists(string all |
            all = this.getContents()
            |
            // match `lgtm[...]` anywhere in the comment
            annotation = all.regexpFind("(?i)\\blgtm\\s*\\[[^\\]]*\\]", _, _)
            or
            // match `lgtm` at the start of the comment and after semicolon
            annotation = all.regexpFind("(?i)(?<=^|;)\\s*lgtm(?!\\B|\\s*\\[)", _, _).trim()
        )
    }

    /** Gets the suppression annotation in this comment. */
    override string getAnnotation() {
        result = annotation
    }

}

/**
 * A noqa suppression comment. Both pylint and pyflakes respect this, so lgtm ought to too.
 */
class NoqaSuppressionComment extends LineSuppressionComment {

    NoqaSuppressionComment() {
        this.getContents().toLowerCase().regexpMatch("\\s*noqa\\s*")
    }

    override string getAnnotation() {
        result = "lgtm"
    }

}


/**
 * The scope of an alert suppression comment.
 */
class SuppressionScope extends @py_comment {

    SuppressionScope() {
        this instanceof SuppressionComment
    }

     /**
     * Holds if this element is at the specified location.
     * The location spans column `startcolumn` of line `startline` to
     * column `endcolumn` of line `endline` in file `filepath`.
     * For more information, see
     * [LGTM locations](https://lgtm.com/help/ql/locations).
     */
     predicate hasLocationInfo(string filepath, int startline, int startcolumn, int endline, int endcolumn) {
       this.(SuppressionComment).covers(filepath, startline, startcolumn, endline, endcolumn)
     }

    /** Gets a textual representation of this element. */
    string toString() {
        result = "suppression range"
    }

}

from SuppressionComment c
select c,                 // suppression comment
       c.getContents(),   // text of suppression comment (excluding delimiters)
       c.getAnnotation(), // text of suppression annotation
       c.getScope()       // scope of suppression